1.boolean
布尔值是一种特殊的数据类型，用于表示真值true和 false。将此数据类型用于跟踪真/假条件的简单标志。
布尔值可以存储在变量中，并分配到字段中，就像任何其他数据类型一样：
def myBooleanVariable = true
boolean untypedBooleanVar = false
booleanField = true
true和false是仅有的两个原始布尔值。但是，可以使用逻辑运算符表示更复杂的布尔表达式。
2.list
Groovy 使用逗号分隔的值列表（用方括号括起来）来表示列表。Groovy列表是普通的JDK java.util.List，因为Groovy没有定义自己的集合类。定义列表文本时使用的具体列表实现是默认的java.util.ArrayList，除非您决定另行指定，我们将在后面看到。
def numbers = [1, 2, 3]
assert numbers instanceof List //true
assert numbers.size() == 3 //true
- 我们定义一个由逗号分隔并用方括号括起来的列表编号，并将该列表分配到变量中
- 该列表是 Java
java.util.List接口的一个实例 - 可以使用
size()该方法查询列表的大小，并显示我们的列表包含3个元素
在上面的示例中，我们使用了同构列表，但您也可以创建包含异构类型值的列表：
def heterogeneous = [1, "a", true]
- 我们的列表包含一个数字，一个字符串和一个布尔值
我们提到，默认情况下，列表文本实际上是java.util.ArrayList的实例，但是由于对as运算符使用类型强制或对变量使用显式类型声明，因此可以对我们的列表使用不同的支持类型：
def arrayList = [1, 2, 3]
assert arrayList instanceof java.util.ArrayList //true
def linkedList = [2, 3, 4] as LinkedList
assert linkedList instanceof java.util.LinkedList //true
LinkedList otherLinked = [3, 4, 5]
assert otherLinked instanceof java.util.LinkedList //true
您可以使用具有正索引或负索引的[]下标运算符（用于读取和设置值）访问列表中的元素，以从列表末尾以及范围访问元素，并使用 leftShift <<运算符将元素追加到列表中：
def letters = ['a', 'b', 'c', 'd']
assert letters[0] == 'a' //true
assert letters[1] == 'b' //true
assert letters[-1] == 'd' //true
assert letters[-2] == 'c' //true
letters[2] = 'C'
assert letters[2] == 'C' //true
letters << 'e'
assert letters[ 4] == 'e' //true
assert letters[-1] == 'e' //true
assert letters[1, 3] == ['b', 'd'] //true
assert letters[2..4] == ['C', 'd', 'e'] //true
- 访问列表的第一个元素（从零开始计数）
- 使用负索引访问列表中的最后一个元素：-1 是列表末尾的第一个元素
- 使用赋值为列表的第三个元素设置新值
- 使用左移运算符
<<在列表末尾追加一个元素 - 一次访问两个元素，返回包含这两个元素的新列表
- 使用范围可访问列表中的值范围，从开始到结束元素位置
由于列表本质上是异构的，因此列表还可以包含其他列表以创建多维列表：
def multi = [[0, 1], [2, 3]]
assert multi[1][0] == 2 //true
- 定义数字列表的列表
- 访问最顶层列表的第二个元素和内部列表的第一个元素
3.数组
Groovy 对数组重用列表表示法，但要使此类文本数组，您需要通过强制或类型声明显式定义数组的类型。
String[] arrStr = ['Ananas', 'Banana', 'Kiwi']
assert arrStr instanceof String[] //true
assert !(arrStr instanceof List) //true
def numArr = [1, 2, 3] as int[]
assert numArr instanceof int[] //true
assert numArr.size() == 3 //true
- 使用显式变量类型声明定义字符串数组
- 断言我们创建了一个字符串数组
- 使用
as运算符创建整数数组 - 断言我们创建了一个基元整数数组
您还可以创建多维数组：
def matrix3 = new Integer[3][3]
assert matrix3.size() == 3 //true
Integer[][] matrix2
matrix2 = [[1, 2], [3, 4]]
assert matrix2 instanceof Integer[][] //true
- 您可以定义新数组的边界
- 或者声明数组而不指定其边界
对数组元素的访问遵循与列表相同的表示法：
String[] names = ['Cédric', 'Guillaume', 'Jochen', 'Paul']
assert names[0] == 'Cédric' //true
names[2] = 'Blackdrag'
assert names[2] == 'Blackdrag' //true
- 检索数组的第一个元素
- 将数组第三个元素的值设置为新值
Groovy一直支持使用方括号的文字列表/数组定义，并避免使用Java风格的大括号，以免与闭包定义冲突。但是，如果大括号紧跟在数组类型声明之后，则闭包定义没有歧义，因此 Groovy 3 及更高版本支持 Java 数组初始化表达式的该变体。
例子：
def primes = new int[] {2, 3, 5, 7, 11}
assert primes.size() == 5 && primes.sum() == 28 //true
assert primes.class.name == '[I' //true
def pets = new String[] {'cat', 'dog'}
assert pets.size() == 2 && pets.sum() == 'catdog' //true
assert pets.class.name == '[Ljava.lang.String;' //true
// traditional Groovy alternative still supported
String[] groovyBooks = [ 'Groovy in Action', 'Making Java Groovy' ]
assert groovyBooks.every{ it.contains('Groovy') } //true
4.map
Groovy有时在其他语言中称为字典或关联数组，具有map功能。映射将键与值相关联，用冒号分隔键和值，每个键/值都用逗号配对，整个键和值用方括号括起来。
def colors = [red: '#FF0000', green: '#00FF00', blue: '#0000FF']
assert colors['red'] == '#FF0000' //true
assert colors.green == '#00FF00' //true
colors['pink'] = '#FF00FF'
colors.yellow = '#FFFF00'
assert colors.pink == '#FF00FF' //true
assert colors['yellow'] == '#FFFF00' //true
assert colors instanceof java.util.LinkedHashMap //true
- 我们定义了字符串颜色名称的映射，与它们的十六进制编码的html颜色相关联
- 我们使用下标符号来检查与密钥关联的内容
- 我们还可以使用属性表示法来断言绿色的十六进制表示
- 类似地，我们可以使用下标表示法来添加新的键/值对
- 或属性表示法，以添加颜色
Groovy 创建的映射实际上是
java.util.LinkedHashMap的实例。
如果您尝试访问地图中不存在的密钥：
assert colors.unknown == null //true
def emptyMap = [:]
assert emptyMap.anyKey == null //true
在上面的示例中，我们使用字符串键，但您也可以使用其他类型的值作为键：
网友评论