pl/sql

PL/SQL

特点：

1. PL/SQL是过程语言。
2. PL/SQL中存在过程构造和数据库访问。
3. 在Oracle服务器和客户机应用程序中使用。
4. 支持大型对象和集合。

PL/SQL块

特点：

1. 它包括一组语句。
2. PL/SQL程序中的基本单元。
3. 将相关的声明和语句进行逻辑分组。
   4.声明对于块总是局部的，在块完成后，将超出范围。

块结构和基本语法要求

PL/SQL程序基本单元是块。
块结构包含以下部分：

• declare:声明部分标志。
• begin:可执行部分标志。
• exception:异常处理部分标志。
• end:程序结束标志。

dbms_output是Oracle提供的包，有以下三个用于输出的函数：

1. dbms_output.put(要输出的内容)：用于输出字符串，但不换行。
2. dbms_output.put_line(要输出的内容)：用于输出一行字符串信息，并换行。
3. dbms_output.new_line:用来输出一个换行，没有参数。
   要使用该方法显示输出数据，要在sqlplus中先执行如下命令set serveroutput on (size n),n表示输出缓冲区的大小，范围在2000~1000000.

变量

• 数据的临时存储。
• 在声明部分中声明。
• 可以在sql语句和过程语句中使用。
• 在可执行部分中赋予新值。
• 使用变量的优点：可重用性，易于维护。
  在PL/SQL块中可以以使用查询语句和数据操纵语句（DML），所以PL/SQL程序是同SQL语言紧密结合在一起的，同直接执行select语句不同这里的select要和into结合，into后跟用于接收查询结果的变量，形式为：

select 列名1，列名2....into 变量1，变量2....from 表明 where 条件;

注意：接收查询结果的变量类型，顺序，个数同select语句的字段类型，顺序，个数要完全一致，并且select语句返回的数据必须是一行，否则引发系统错误，要返回多行，可以使用游标。程序通过把数据提取到变量中，可以进行复杂处理，完成sql语句不能实现的功能，并以多种方式输出。
事例如下，查询雇员编号为7788的雇员姓名和工资。

declare  --定义部分
v_name varchar2(10);
v_sal number(5);
begin   --可执行部分
  select ename,sal into v_name,v_sal
  from emp where empno=7788;
  --在程序中输出变量的值
  dbms_output.put_line('雇员'||v_name||'的工资为'||v_sal);
end;   --结束标志

数据类型

纯量类型有

• 数值
  binary_integer:整数型，带符号
  number:数值型
• 字符
  char:定长字符型，最大32767个字符,定义时要指明宽度（以字节为单位），如不指明，默认宽度为1，定长字符串在显示输出时具有对齐效果。
  varchar2:变长字符型，最大32767个字符
  long:变长字符型，最大2GB
  long raw
  raw
  rawid
• 逻辑
  boolean:布尔型，用于存储逻辑值true和false
• 日期
  date:日期型，用于存储日期和时间。内部使用7个字节，包括年，月日，小时，分钟，秒数。默认格式为：DD-MON-YY,如07-8月-03表示2003年8月7日。

组合类型有

• 记录
  record
• 表
  table

大对象类型lob
用来存储非结构化数据，长度可达4GB。lob类型可以存储视频，音频，图片，支持随机访问，存储的数据可以位于数据库内或数据库外，具有四种类型：bfile,blob,clob,nclob。但是操纵大对象需要使用Oracle提供的dbms_lob包。

变量定义

1. 变量名(constant)数据类型(not null)(:=值)(default值)；
   说明：关键字constant用来说明定义的变量是常量，如果是常量，必须有赋值部分进行赋值。关键值not null用来说明变量不能为空。:=或default用来为变量赋值。

2. 变量的声明还可以根据数据库表的字段进行定义，方法是在表的字段名或已经定义的变量后加%type,将其当作数据类型。定义字段变量的方法：
   变量名 表明.字段名%type;

declare
 v_ename emp.ename%type;
begin
select ename into v_ename
from emp
where empno=7788;
dbms_output.put_line('雇员姓名:'||v_ename);
end;

复合类型

具有内部成员的类型，该成员可以被单独操作。通常，该类型的变量由一个或多个标量类型变量组成。
示例：

declare
--定义保存雇员信息的记录类型
type t_emp_record is record(
empno number,
ename emp.ename%type,
job emp.job%type,
sal emp.sal%type
);
--定义保存雇员信息的记录变量
v_emp1  t_emp_record;
v_emp2  t_emp_record;
v_empno emp.empno%type;
begin
  v_empno:='&雇员编号';
  --获取一条记录并保存到记录变量中
  select empno,ename,job,sal into v_emp1
  from emp where empno=v_empno;
  dbms_output.put_line('编号:'||v_emp1.empno||'姓名:'||v_emp1.ename||'职务:'||v_emp1.job||'工资:'||v_emp1.sal);
  --具有相同类型的两个记录可以相互赋值
  v_emp2:=v_emp1;
end;

%rowtype操作符，声明一个与数据表中各类型相同的记录。
定义方法：记录变量名 表名%rowtype
获得记录变量的字段的方法：记录变量名.字段名，如：emp_record.ename;
示例：

declare
--定义记录变量
emp_record emp%rowtype;
begin
  --取出一条记录
  select * into emp_record from emp where empno=7788;
  --输出记录变量中的字段值
  dbms_output.put_line('姓名:'||emp_record.ename);
  dbms_output.put_line('工资:'||emp_record.sal);
  dbms_output.put_line('职务:'||emp_record.job); 
end;