核心公式
（纹理采样）漫反射光 = 入射光线强度 * 纹素值 * 材质的漫反射系数 * 取值为正数 ( 表面法线方向 · 光源方向 ) ;
（切线空间纹理映射）漫反射光 = 入射光线强度 * 纹素值 * 材质的漫反射系数 * 取值为正数 ( 切线光源方向 · 切线法线方向 ) ;
（世界空间纹理映射）漫反射光 = 入射光线强度 * 纹素值 * 材质的漫反射系数 * 取值为正数 ( 世界光源方向 · 世界法线方向 ) ;
两种方法：
切线空间下计算光照：光照方向、视角方向需要变换到切线空间计算。
世界空间下计算光照：把采样得到的法线方向变换到世界空间下，再和世界空间下的光照和视角方向计算。
效率上：第一种优于第二种，第一种在顶点着色器就完成对光照方向和视角的变换，第二种要对法线采样，必须在片元着色器中实现，即进行一次矩阵操作。
通用性：第二种优于第一种，如使用Cubemap进行环境映射时，需要使用世界空间下下的反射方向对Cubemap采样时，那就需要世界空间下的法线方向。
切线空间下计算
计算光照、视角方向从模型到切线空间的矩阵：因为这个变换只包含平移和旋转（正交矩阵），所以变换的逆矩阵就是转置矩阵，即将切线（x）、副切线（y）、法线（z）按行排列。需要注意对于非统一缩放物体，这里的法线计算就是错误的，详细可见这里。
Shader "Unlit/Normal Map In Tangent Space"
{
Properties
{
_Color("Color Tint", Color)=(1,1,1,1)
_MainTex ("Texture", 2D) = "white" {} //法线纹理
_BumpMap ("Bump Map",2D)="bump"{} // 控制凹凸程度
_BumpScale("Bump Sca1e",Float)=1.0
_Specular("specular",Color )=(1,1,1,1)
_Gloss("Gloss",Range(8.0,256)) = 20
}
SubShader
{
Pass
{
Tags { "LightMode"="ForwardBase"}
CGPROGRAM
//定义顶点着色器和片元着色器的名字
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
//得到纹理的缩放（scale）和平移（translation） ;
//_MainTex_ST.xy 存储的是缩放值；_MainTex_ST.zw是偏移值
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION; //取得顶点位置
float3 normal : NORMAL;//切线空间的确是是通过(存储到模型里面)法线和切线确定的
float4 tangent : TANGENT;//tangent.w是用来确定切线空间中坐标的方向
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;//剪裁空间下的顶点坐标
float4 uv : TEXCOORD0;//切线空间下 平行光的方向
float3 lightDir: TEXCOORD1; //世界空间下的顶点坐标
float3 viewDir : TEXCOORD2;//设为float4，xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
};
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //法线从模型空间=》世界空间
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw; //顶点坐标从模型空间=》世界空间
// 计算副切线
//float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
//切线空间矩阵
//float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);
//内置函数 //调用这个宏之后，会得到一个矩阵 rotation ，这个矩阵用来把模型空间下的方向转换为切线空间下的
TANGENT_SPACE_ROTATION;
// 光源在切线空间下的方向
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
//视角在切线空间下的方向
o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;
return o;
}
fixed4 frag (v2f i):SV_Target
{
fixed3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentViewDir = normalize(i.viewDir);
//采样法线纹理
fixed4 packedNormal = tex2D(_BumpMap, i.uv.zw);
// 切线空间法向量
fixed3 tangentNormal;
// 如果没有标记为"Normal map"
tangentNormal.xy = (packedNormal.xy * 2 - 1) * _BumpScale;
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));
//如果标记为"Normal map"，可以使用内置函数
/*tangentNormal = UnpackNormal(packedNormla);
tangentNormal.xy = _BumpScale;
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy))); */
// 在切线空间中计算光照
fixed3 albedo = tex2D(_MainTex, i.uv).rgb* _Color.rgb;
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//漫反射光
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
//高光反射
fixed3 halfDir = normalize (tangentLightDir + tangentViewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb* pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
return fixed4(ambient + diffuse +specular,1.0);
}
ENDCG
}
}
}
世界空间下下的计算
Shader "Unlit/NormalMapWorldSpace"
{
Properties{
_Color("Color Tint",Color) = (1,1,1,1)
_MainTex("Main Tex", 2D) = "white"{}
_BumpMap("NormalMap",2D) = "bump"{}
_BumpScale("Bump Scale" , Float) = 1.0
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(8.0,256)) = 20
}
SubShader{
Pass{
Tags { "LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
//Ttow0,1,2存储切线空间到世界空间的变换矩阵
//多余的w分量用以存储世界空间下的顶点位置
struct v2f {
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtoW0 : TEXCOORD1; // 切线到世界空间变换矩阵3x3。w分量作为世界空间顶点位置，因为计算相同，所以放一起3x4。
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; // xy存主纹理的纹理坐标
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw; // zw存凹凸感的纹理坐标
// 计算世界空间下的顶点法线、切线、副切线
float3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldNormal(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal,worldTangent) * v.tangent.w;
// 变换矩阵，转置即可，每一行按照列摆放
o.TtoW0 = float4(worldTangent.x ,worldBinormal.x ,worldNormal.x ,worldPos.x);
o.TtoW1 = float4(worldTangent.y ,worldBinormal.y ,worldNormal.y ,worldPos.y);
o.TtoW2 = float4(worldTangent.z ,worldBinormal.z ,worldNormal.z ,worldPos.z);
return o;
}
fixed4 frag(v2f i) : SV_TARGET{
float3 worldPos = float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w); //把世界空间下的顶点位置的xyz分量分别存储在了这些变量的w分量中
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
//saturate函数（如果x取值小于0，则返回值为0。如果x取值大于1，则返回值为1。若x在0到1之间，则直接返回x的值.）
//sqrt :求 x 的平方根
fixed3 bump = UnpackNormal(tex2D(_BumpMap,i.uv.zw));
bump.xy *= _BumpScale;
bump.z = sqrt(1.0 - saturate(dot(bump.xy,bump.xy)));
//转换到世界空间下，通过点乘来实现矩阵的每一行和法线相乘
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
}
ASE 连接
效果对比.png
网友评论