Unity Shader系列文章：Unity Shader目录-初级篇
Unity Shader系列文章：Unity Shader目录-中级篇
效果：
菲涅耳反射，注意模型边界处的反射
原理：
菲涅耳反射描述了一种光学现象，即当光线照射到物体表面上时，一部分发生反射，一部分进入物体内部，发生折射或散射。被反射的光和入射光之间存在一定的比率关系，这个比率关系可以通过菲涅耳等式进行计算。
一个经常使用的例子是，当你站在湖边，直接低头看脚边的水面时，你会发现水几乎是透明的，你可以直接看到水底的小鱼和石子。但是，当你抬头看远处的水面时，会发现几乎看不到水下的情景，而只能看到水面反射的环境。这就是所谓的菲涅耳效果，几乎任何物体都或多或少包含了菲涅耳效果。
真实世界的菲涅耳等式是非常复杂的，但在实时渲染中，我们通常会使用一些近似公式来计算。其中一个著名的近似公式就是Schlick菲涅耳近似等式：
其中是一个反射系数，用于控制菲涅尔反射的强度，v是视角方向，n是表面法线。
另一个比较广泛的等式是Empricial菲涅耳近似等式:
其中是控制项。
shader代码：
// 菲涅尔反射
Shader "Custom/Fresnel"
{
Properties
{
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_FresnelScale ("Fresnel Scale", Range(0, 1)) = 0.5 // 菲涅尔反射强度
_Cubemap ("Reflection Cubemap", Cube) = "_Skybox" { }// 立方体纹理
}
SubShader
{
Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }
Pass
{
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
// 编译指令，保证在pass中得到正确的光照变量
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed _FresnelScale;
samplerCUBE _Cubemap;
// 应用传递给顶点着色器的数据
struct a2v
{
float4 vertex: POSITION; // 语义：顶点坐标
float3 normal: NORMAL; // 语义：法线
};
// 顶点着色器传递给片元着色器的数据
struct v2f
{
float4 pos: SV_POSITION; // 语义：裁剪空间顶点坐标
float3 worldPos: TEXCOORD0;
fixed3 worldNormal: TEXCOORD1;
fixed3 worldViewDir: TEXCOORD2;
fixed3 worldRefl: TEXCOORD3;
SHADOW_COORDS(4) // 声明一个用于对阴影纹理采样的坐标 (这个宏参数需要是下一个可用的插值寄存器的索引值，这里是4)
};
// 顶点着色器函数
v2f vert(a2v v)
{
v2f o;
// 将顶点坐标从模型空间变换到裁剪空间
// 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.pos = UnityObjectToClipPos(v.vertex);
// 将顶点坐标从模型空间变换到世界空间
o.worldNormal = UnityObjectToWorldNormal(v.normal);
// 将法线从模型空间变换到世界空间
// 等价于o.worldNormal = mul(v.normal, (float3x3)unity_ObjectToWorld);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
// 观察向量
o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
// 反射向量
o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
// 计算声明的阴影纹理坐标
TRANSFER_SHADOW(o);
return o;
}
// 片元着色器
fixed4 frag(v2f i): SV_Target
{
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldViewDir = normalize(i.worldViewDir);
// 单位光向量
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
// 反射，对立方体纹理进行采样，此处并没有对worldRefl进行归一化，因为texCUBE参数仅仅只需要反射的方向
fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb;
// 菲涅尔反射
fixed fresnel = _FresnelScale + (1 - _FresnelScale) * pow(1 - dot(worldViewDir, worldNormal), 5);
// 漫反射
fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));
// 环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// 计算光照衰减和阴影
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
fixed3 color = ambient + lerp(diffuse, reflection, saturate(fresnel)) * atten;
return fixed4(color, 1.0);
}
ENDCG
}
}
FallBack "Reflective/VertexLit"
}
网友评论