自己实现一个SAP WebClient UI Repositor

For traditional ABAP artifact we have a handy tool Repository Information System in SE80 which can help us to efficiently locate the objects according to various search criteria.

For example, see my blog A small tip to find message id and number by repository information system.

However, for CRM WebUI Component, it is not supported by this information system. Several days ago I was asked by my colleague to provide him a list of all UI Component which have utilized the Genil model node “Product”.
Requirement: find all UI components which have context node bound to Genil model node “Product”.

Since there is no existing tool, so I write one.

REPORT zui_context_node_scan.

DATA: lt_context_node TYPE TABLE OF vseoextend-clsname,
      lo_cls          TYPE REF TO cl_bsp_wd_context_node,
      lv_total        TYPE int4,
      lt_result       TYPE TABLE OF zwebuicontextnam.

DELETE FROM zwebuicontextnam.
SELECT clsname INTO TABLE lt_context_node FROM vseoextend WHERE refclsname =
   'CL_BSP_WD_CONTEXT_NODE'.

lv_total = lines( lt_context_node ).
LOOP AT lt_context_node ASSIGNING FIELD-SYMBOL(<node>).
  TRY.
      CREATE OBJECT lo_cls TYPE (<node>).
      ASSIGN lo_cls->('BASE_ENTITY_NAME') TO FIELD-SYMBOL(<name>).
      APPEND INITIAL LINE TO lt_result ASSIGNING FIELD-SYMBOL(<result>).
      <result> = VALUE #( context_node_cls = <node> bol_node_name = <name> ).
      CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
        EXPORTING
          percentage = ( sy-tabix * 100 ) / lv_total
          text       = | index: { sy-tabix }: { <node> } |.
      "WRITE: / 'context node class: ', <node>, ' bol node:', <name>.
    CATCH cx_root INTO DATA(cx_root).
      WRITE: / cx_root->get_text( ), ' class: ' , <node>.
      CONTINUE.
  ENDTRY.
ENDLOOP.

INSERT zwebuicontextnam FROM TABLE lt_result.

Use this report, first I get a list of all UI component context node class from table vseoextend based on the assumption that a class could be considered as context node class as long as it inherits from super class CL_BSP_WD_CONTEXT_NODE.

The name of bound Genil model name is stored in attribute BASE_ENTITY_NAME of context node class.

So I finally store context node class name and bound Genil model node name to an Z table:

Now I run report and can simply query the Z table via BOL_NODE_NAME = Product:

And get to know that in my system there are totally 673 context node which are bound to Product Genil model node.

Since my colleague needs the UI component name, so I wrote another report to extract the UI component name based on context node class name:

REPORT zui_get_app_name_by_context.

DATA: lt_context_node TYPE TABLE OF zwebuicontextnam,
      lt_app          TYPE TABLE OF o2pagpar,
      lt_ui           TYPE TABLE OF o2pagpar-applname.

SELECT * INTO TABLE lt_context_node FROM zwebuicontextnam WHERE bol_node_name = 'Product'.

CHECK sy-subrc = 0.

SELECT * INTO TABLE lt_app FROM o2pagpar FOR ALL ENTRIES IN lt_context_node WHERE type = lt_context_node-context_node_cls.

SORT lt_app BY applname ASCENDING.

SELECT applname INTO TABLE lt_ui FROM o2pagpar FOR ALL ENTRIES IN lt_context_node WHERE type = lt_context_node-context_node_cls.

SORT lt_ui.

DELETE ADJACENT DUPLICATES FROM lt_ui.

Now the internal table lt_app contains the concrete information of UI component name and view name which the context node is in.