image
看了很多网上 three js 的内容，关于特效的内容实在太少，所以就简单翻译一下 Jaume Sanchez! 大神的爆炸特效，最终效果点击这里： DEMO演示
这个教程中演示了如何用 Perlin Noise 来改变一个球体的顶点，实现爆炸的效果，演示创建动画形状的步骤, 它还教如何增加一些变化的失真和如何添加颜色。
这个场景是用threejs创建的，在下面的内容中，已经假设读者对threejs有过了基本的了解，其中的 GLSL 部分的代码也可用于其他的 WebGL/OpenGL 库，相信它应该也很容易翻译成微软的 High Level Shader Language。
如果您之前对 threejs没有任何了解，建议看一下官方的例子和相关的文档，对webGL的3D编程有个基本的了解。当然下面的内容会将这块尽可能的保持简单。
image
首先创建一个场景
这个场景中包含了最简单的内容，就是一个球和一个相机
首先是html的部分
<!doctype html>
<html lang="en">
<head>
<title>Perlin noise | Fireball explosion</title>
<meta charset="utf-8">
</head>
<body>
<div id="container"></div>
</body>
<script src="js/Three.js"></script>
<script type="text/javascript" id="mainCode">
// Put the main code here
</script>
</html>
mainCode里加入如下的内容
var container,
renderer,
scene,
camera,
material,
mesh,
start = Date.now(),
fov = 30;
window.addEventListener( 'load', function() {
// 找到 DOM
container = document.getElementById( "container" );
// 创建场景
scene = new THREE.Scene();
// 加入一个相机
camera = new THREE.PerspectiveCamera(
fov,
window.innerWidth / window.innerHeight,
1,
10000 );
camera.position.z = 100;
camera.target = new THREE.Vector3( 0, 0, 0 );
scene.add( camera );
create(); //创建内容
// 创建一个renderer并加入到前面的DOM中
renderer = new THREE.WebGLRenderer();
renderer.setSize( window.innerWidth, window.innerHeight );
container.appendChild( renderer.domElement );
render();
} );
function render() {
animat();
// let there be light
renderer.render( scene, camera );
requestAnimationFrame( render );
}
create这个方法里的内容
function create(){
// 外部读取贴图
const texture = new THREE.TextureLoader().load('img/explosion.png')
// 创建一个 shader 材质
material = new THREE.ShaderMaterial( {
uniforms: {
tExplosion: {
type: "t",
value: texture
},
time: {
type: "f",
value: 0.0
}
},
vertexShader: vertexShader,
fragmentShader: fragmentShader
} );
// 创建一个球体并贴上材质
mesh = new THREE.Mesh(
new THREE.IcosahedronGeometry(20, 4 ), // 20, 4
material
);
scene.add(mesh);
}
这里使用的贴图是
image
保存好并放到一个正确的目录，保证TextureLoader能找到它
为了编写代码方便，我这里使用了一些es6的语法，毕竟都2018年了，几乎大部分的浏览器都完美的支持了es6，当然为了保险，最终发布的时候你可以考虑用babel转一下成es5，这个就不在本次教程内了
这里最关键的就是 vertexShader 和 fragmentShader 这两个变量里的内容了，下面是原理解释，不感兴趣的同学可以直接跳到下面去获取这两个代码
原理解释
球体是不错, 但非常枯燥，因为每个点的位置都是平均分布的
我们必须打乱顶点位置, 以获得有趣的形状: 土豆, 斑点, 恒星, 爆炸..。
这里的主要思想是：打乱每个顶点正常的朝向。假设有从我们的球体的中心到每个顶点的线, 每个顶点一行。最初, 所有这些线都是相同的长度 (球体的半径)。如果我们做一些更长, 一些更短, 我们将会获得一个有趣的混乱网格。
image
随机出来的是不错, 很混乱但效果出来不吸引人。我们希望打乱顶点是基于一些随机但可控的, 这里的 Perlin Noise 柏林噪音算法可以出来拯救一下我们小世界。
我将使用阿诗玛的 webgl-噪声,
), 一组梦幻般的程序噪声着色器，而且最重要的是兼容 webgl。
在着色器中有柏林噪声的许多替代方案: 标准实现、单纯形实现、杂色纹理。选择哪一个取决于噪声的使用和要求。这里的规则是越复杂, 越慢。如果您需要大量的噪声值, 您可能需要一个纹理贴图。
让我们沿着法线来干扰顶点: 我们希望通过一些标量因子乘以法线, 这样它就会缩放 (从中心到顶点的线缩小或增大, 并且由于它定义了顶点位置, 顶点本身会向内或向外移动)。这就是我们得到的噪音值。噪声的坐标基于在修改前的法线, 并且噪声值被调制以适合所需的刻度。我不是直接使用噪声函数, 而是使用湍流函数， 这将创建真正有趣的形状。我们鼓励您尝试不同的噪声函数, 并为噪声函数提供不同的参数和周期。
我做一个刚度失真, 添加一个系数基于较大的噪声 (低频噪声), 以扰乱球体形状。请尝试更改杂色和 b 的值, 以查看每个影响生成的形状的方式。
在处理噪声函数时，有一点非常重要： 您通常会传递具有时间连贯性的参数, 因为您不希望网格突然改变形状。这是通过使用一些值, 它是相同的每个帧为您的顶点或片段: 它可以是一个属性或统一, 但我通常喜欢使用 UV 坐标, 位置或法线。通常在转换为眼坐标之前。
我将噪声存储为假的环境遮挡因子, 这在渲染形状时很有用, 可以显示凸起和凹陷区域。
现在, 我们计算顶点的新位置, 通过位移因子沿其法线移动顶点: 像采取原始位置和增加正常乘以我们的噪声。
最终的shader出来如下
const vertexShader = `
//
// GLSL textureless classic 3D noise "cnoise",
// with an RSL-style periodic variant "pnoise".
// Author: Stefan Gustavson (stefan.gustavson@liu.se)
// Version: 2011-10-11
//
// Many thanks to Ian McEwan of Ashima Arts for the
// ideas for permutation and gradient selection.
//
// Copyright (c) 2011 Stefan Gustavson. All rights reserved.
// Distributed under the MIT license. See LICENSE file.
// https://github.com/ashima/webgl-noise
//
vec3 mod289(vec3 x)
{
return x - floor(x * (1.0 / 289.0)) * 289.0;
}
vec4 mod289(vec4 x)
{
return x - floor(x * (1.0 / 289.0)) * 289.0;
}
vec4 permute(vec4 x)
{
return mod289(((x*34.0)+1.0)*x);
}
vec4 taylorInvSqrt(vec4 r)
{
return 1.79284291400159 - 0.85373472095314 * r;
}
vec3 fade(vec3 t) {
return t*t*t*(t*(t*6.0-15.0)+10.0);
}
// Classic Perlin noise
float cnoise(vec3 P)
{
vec3 Pi0 = floor(P); // Integer part for indexing
vec3 Pi1 = Pi0 + vec3(1.0); // Integer part + 1
Pi0 = mod289(Pi0);
Pi1 = mod289(Pi1);
vec3 Pf0 = fract(P); // Fractional part for interpolation
vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
vec4 iy = vec4(Pi0.yy, Pi1.yy);
vec4 iz0 = Pi0.zzzz;
vec4 iz1 = Pi1.zzzz;
vec4 ixy = permute(permute(ix) + iy);
vec4 ixy0 = permute(ixy + iz0);
vec4 ixy1 = permute(ixy + iz1);
vec4 gx0 = ixy0 * (1.0 / 7.0);
vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
gx0 = fract(gx0);
vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
vec4 sz0 = step(gz0, vec4(0.0));
gx0 -= sz0 * (step(0.0, gx0) - 0.5);
gy0 -= sz0 * (step(0.0, gy0) - 0.5);
vec4 gx1 = ixy1 * (1.0 / 7.0);
vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
gx1 = fract(gx1);
vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
vec4 sz1 = step(gz1, vec4(0.0));
gx1 -= sz1 * (step(0.0, gx1) - 0.5);
gy1 -= sz1 * (step(0.0, gy1) - 0.5);
vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);
vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
g000 *= norm0.x;
g010 *= norm0.y;
g100 *= norm0.z;
g110 *= norm0.w;
vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
g001 *= norm1.x;
g011 *= norm1.y;
g101 *= norm1.z;
g111 *= norm1.w;
float n000 = dot(g000, Pf0);
float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
float n111 = dot(g111, Pf1);
vec3 fade_xyz = fade(Pf0);
vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
return 2.2 * n_xyz;
}
// Classic Perlin noise, periodic variant
float pnoise(vec3 P, vec3 rep)
{
vec3 Pi0 = mod(floor(P), rep); // Integer part, modulo period
vec3 Pi1 = mod(Pi0 + vec3(1.0), rep); // Integer part + 1, mod period
Pi0 = mod289(Pi0);
Pi1 = mod289(Pi1);
vec3 Pf0 = fract(P); // Fractional part for interpolation
vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
vec4 iy = vec4(Pi0.yy, Pi1.yy);
vec4 iz0 = Pi0.zzzz;
vec4 iz1 = Pi1.zzzz;
vec4 ixy = permute(permute(ix) + iy);
vec4 ixy0 = permute(ixy + iz0);
vec4 ixy1 = permute(ixy + iz1);
vec4 gx0 = ixy0 * (1.0 / 7.0);
vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
gx0 = fract(gx0);
vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
vec4 sz0 = step(gz0, vec4(0.0));
gx0 -= sz0 * (step(0.0, gx0) - 0.5);
gy0 -= sz0 * (step(0.0, gy0) - 0.5);
vec4 gx1 = ixy1 * (1.0 / 7.0);
vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
gx1 = fract(gx1);
vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
vec4 sz1 = step(gz1, vec4(0.0));
gx1 -= sz1 * (step(0.0, gx1) - 0.5);
gy1 -= sz1 * (step(0.0, gy1) - 0.5);
vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);
vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
g000 *= norm0.x;
g010 *= norm0.y;
g100 *= norm0.z;
g110 *= norm0.w;
vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
g001 *= norm1.x;
g011 *= norm1.y;
g101 *= norm1.z;
g111 *= norm1.w;
float n000 = dot(g000, Pf0);
float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
float n111 = dot(g111, Pf1);
vec3 fade_xyz = fade(Pf0);
vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
return 2.2 * n_xyz;
}
// Include the Ashima code here!
varying vec2 vUv;
varying float noise;
uniform float time;
float turbulence( vec3 p ) {
// float w = 100.0;
float t = -.5;
for (float f = 1.0 ; f <= 10.0 ; f++ ){ // 凸起的数量
float power = pow( 2.0, f );
t += abs( pnoise( vec3( power * p ), vec3( 10.0, 10.0, 10.0 ) ) / power );
}
return t;
}
void main() {
vUv = uv;
noise = 10.0 * -.10 * turbulence( .5 * normal + time );
float b = 5.0 * pnoise( 0.05 * position + vec3( 2.0 * time ), vec3( 100.0 ) );
float displacement = - 10. * noise + b;
// float displacement = - 10. * noise + time; // 波浪起伏度
vec3 newPosition = position + normal * displacement;
gl_Position = projectionMatrix * modelViewMatrix * vec4( newPosition, 1.0 );
}
`
const fragmentShader = `
varying vec2 vUv;
varying float noise;
uniform sampler2D tExplosion;
// uniform float time;
float random( vec3 scale, float seed ){
return fract( sin( dot( gl_FragCoord.xyz + seed, scale ) ) * 43758.5453 + seed ) ;
}
void main() {
float r = .01 * random( vec3( 12.9898, 78.233, 151.7182 ), 0.0 );
vec2 tPos = vec2( 0, 1.3 * noise + r );
vec4 color = texture2D( tExplosion, tPos );
gl_FragColor = vec4( color.rgb, 1.0 );
}
`
把这两个变量的内容加入 create 函数的最前端
最后在 render 中的函数 animat(); 的内容
function animat(){
if(!material) return
material.uniforms[ 'time' ].value += .0025
}
image
网友评论