1.荷载组合的含义

在ANSYS中，工况组合是指在不同结果数据之间进行运算处理，即当前处于数据库的荷载工况结果数据和另一独立结果文件中的荷载工况结果数据之间进行运算。这个过程可以简单的描述如下：

荷载组合大体上可以分为两种方法实现，一种是通过荷载工况文件的组合；另一种便是通过结果文件进行荷载组合。
在具体介绍这两种方法之前，首先罗列出工况组合常用的命令流：

Lcwrite:写结果文件
LCfile:从结果文件中创建工况
LCDEF:从结果数据中创建一个工况
LCFACT:工况组合分项系数
LCOPER:对荷载工况进行操作
LCASE:读取指定工况

注意：荷载工况组合只适用于弹性计算中。

2.实现方式

1）荷载工况文件组合

这种方法主要是分别采用单独的APDL进行运算，并将运算结果分别写进不用的计算文件，通过对结果不同数据文件的操作来实现工况组合。

命令流典型过程

/SOLU
... ...
finish
/POST1
... ...
!定义荷载工况1
LCDEF,1,1
!形成后续工况组合可以调用的工况文件lcase1，工况号1
LCWRITE,1,'lcase1',' ',' '
FINISH
/SOLU
... ...
finish
/POST1
... ...
!定义荷载工况2
LCDEF,2,1
!形成后续工况组合可以调用的工况文件lcase2，工况号2
LCWRITE,2,'lcase2',' ',' '
FINISH
/SOLU
... ...
finish
/POST1
... ...
!定义荷载工况3
LCDEF,3,1
!形成后续工况组合可以调用的工况文件lcase3，工况号3
LCWRITE,3,'lcase3',' ',' '
FINISH
/POST1
!从载荷工况文件创建载荷工况
LCFILE,1,'lcase1','l01',' '
LCFACT,1,1.2, !分项系数1.2
LCFILE,2,'lcase2','l02',' '
LCFACT,2,1.4, !分项系数1.4
LCFILE,3,'lcase3','l03',' '
LCFACT,3,1.3, !分项系数1.3
LCASE,1 !将载荷工况1读入内存
LCOPER,ADD,2, , , !组合：1.2恒+1.4活
LCWRITE,12 !写当前载荷工况到文件jobname.12
LCASE,3 !将载荷工况3读入内存
LCOPER,ADD,12, , , !组合：1.2恒+1.4活+1.3地震

2）结果数据文件组合

这种方法主要是指在同一个计算文件中设置不同的荷载步，通过不同荷载步之间的组合来实现荷载组合。这种方法相对于文件组合来讲，使用频率更高。

典型命令流过程如下：

FINISH
………
/SOLU
TIME,1
……
SOLVE
TIME,2
.....
SOLVE
……
/POST1
Lcdef,1,1,last !定义恒载工况
Lcdef,2,2,last !定义活载工况
Lcfact,1,1.2 !恒载分项系数
Lcfact,2,1.4 !活载分项系数
Lcase,1
LCOPER,ADD,2, , , !组合：1.2恒+1.4活
Lcwrite,12 !组合结果写入文件。

3.案例

下面以一个简单的悬臂梁为例，说明其操作过程，首先声明，该案例并无任何实际工程意义，具体情况还需具体分析。
悬臂梁采用Q235钢材，悬臂长度2m，截面类型为工字型钢，截面为140886*6，恒载包括梁自重以及额外的2KN/m,活载为1KN/m,试用ANSYS进行1.2恒+1.4活的组合。

命令流

!！完整案例悬臂梁
!===============================
finish
/clear
/filname,xuanbiliang
!单位：N,mm
!单元，截面，材料===============================
/prep7
et,1,beam189
SECTYPE,   1, BEAM, I, beam_I
SECOFFSET, CENT 
SECDATA,88,88,140,6,6,6
!
mp,ex,1,2.1e5    !钢
mp,prxy,1,0.3
mp,dens,1,7850e-12
!建模===============================
k,1
k,2,2000
k,3,500,500  !方向点
l,1,2
lsel,all
latt,1,,1,,3,,1   !方向点3
lesize,all,,,10
lmesh,all
!加荷载求解==============================
/solu
dk,1,all
!恒载计算
time,1
ACEL,0,9800,  !注意是y方向的重力加速度
SFBEAM,all,1,PRES,2   !梁上线均布荷载
solve
!活载计算
time,2
ACEL,0,0,  !为啥重力加速度要设置为0？
SFBEAM,all,1,PRES,1
solve
!结果显示==============================
/post1
/eshape,1
set,1,last     !读取结果，第1个荷载步
PLNSOL, U,Y    !绘图：y向位移
!
set,2,last     !读取结果，第2个荷载步
PLNSOL, U,Y
!荷载工况组合==============================
!1.创建工况
lcdef,1,1,last  !从结果数据中创建工况1，对于第1个荷载步最后一个子步
lcdef,2,2,last  !从结果数据中创建工况2，对于第2个荷载步最后一个子步
!2.定义各工况对应的乘积因子
lcfact,1,1.2   !工况1*1.2，形成新的工况1
lcfact,2,1.4   !工况2*1.4，形成新的工况2
!3.读取指定的工况,操作
lcase,1     !读取工况1为当前的工况
lcoper,add,2   !对当前工况进行操作，当前工况+工况2
!4.绘图显示
PLNSOL, U,Y
!end==============================

结果
1x恒载---作用下的变形图：
1x活载---作用下的变形图：
1.2x恒载+1.4x活载---作用下的变形图
组合验证：
通过位移最大值验证工况组合叠加。
恒载最大位移：3.58803
活载最大位移：1.6764
组合最大位移：6.65259
3.588031.2+1.67641.4=6.65259