Shader学习4——Phong

Phong光照模型是一种提升物体表面高光的光照模型，高光的强度和范围取决于光源相对物体的方向和观察者相对物体的方向。
Phong高光反射颜色 = 入射光颜色 X 高光反射颜色 X max(0,Dot(视角方向，反射方向))^反射系数
Phong适合模拟塑料，比"反射"材质表现出的介质更光滑一些，适合模拟玻璃、水、冰等高反光特性的介质
结果如下：

image.png

代码如下：

Shader "Unlit/高光"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular", Color) = (1,1,1,1)
        _Gloss("Gloss",Range(8.0,256)) = 20
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "LightMode"="ForwardBase"}
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float3 normal:NORMAL;
                float4 vertex : SV_POSITION;
                float3 worldPos : TEXCOORD1;
            };
            
            fixed4 _Diffuse;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;

            v2f vert (a2v v)
            {
                v2f o;
                //顶点坐标转换
                o.vertex = UnityObjectToClipPos(v.vertex);
                //获取法线（统一到世界坐标系下）。
                o.normal = UnityObjectToWorldNormal(v.normal);
                //获取UV
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                //顶点坐标转世界坐标
                o.worldPos=UnityObjectToWorldDir(v.vertex);
                //mul(unity_ObjectToWorld,v.vertex).xyz;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //获取平行光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                //获取归一化的法线
                fixed3 worldNormal = normalize(i.normal);
                //fixed3 worldNormal = i.normal;
                //获取环境光的方向
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
                //兰伯特：漫反射颜色 = 光源颜色 x 材质的漫反射颜色 x Max(0,Dot(法线，指向光源的方向))
                //计算光照强度
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

                //高光反射颜色 = 入射光颜色 X 高光反射颜色 X max(0,Dot(视角方向，反射方向))^反射系数
                //计算反射方向
                fixed3 reflectDir = normalize(reflect(-worldLight,worldNormal));
                //获取视线方向
                fixed3 view = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
                //计算高光反射
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,view)),_Gloss);

                //叠加
                fixed3 color = ambient + diffuse + specular;

                //获取贴图颜色
                fixed4 col = tex2D(_MainTex, i.uv);
                //将贴图颜色与顶点计算的颜色相乘 
                col=fixed4(col.rgb*color.rgb,1.0);
                return col;
            }
            ENDCG
        }
    }
}