探索底层原理，积累从点滴做起。大家好，我是Mars。

往期回顾

iOS底层原理探索 — OC对象的本质
iOS底层原理探索 — class的本质
iOS底层原理探索 — KVO的本质
iOS底层原理探索 — KVC的本质
iOS底层原理探索 — Category的本质(一)
iOS底层原理探索 — Category的本质(二)
iOS底层原理探索 — 关联对象的本质
iOS底层原理探索 — block的本质(一)
iOS底层原理探索 — block的本质(二)
iOS底层原理探索 — Runtime之isa的本质
iOS底层原理探索 — Runtime之class的本质
iOS底层原理探索 — Runtime之消息机制
iOS底层原理探索 — RunLoop的本质
iOS底层原理探索 — RunLoop的应用
iOS底层原理探索 — 多线程的本质
iOS底层原理探索 — 多线程的经典面试题
iOS底层原理探索 — 多线程的“锁”
iOS底层原理探索 — 多线程的读写安全
iOS底层原理探索 — 内存管理(一)
iOS底层原理探索 — 内存管理(二)

前言

内存管理在APP开发过程中占据着一个很重要的地位，在iOS中，系统为我们提供了ARC的开发环境，帮助我们做了很多内存管理的内容，其实在MRC时代，内存管理对于开发者是个很头疼的问题。我们通过iOS底层原理探索 — 内存管理(一)、
iOS底层原理探索 — 内存管理(二)两篇文章大致分析了iOS中内存管理的原理。今天我们继续分析weak的实现原理。

weak 弱引用

int main(int argc, char * argv[]) {
    @autoreleasepool {
        NSObject *objc = [[NSObject alloc] init];
        __weak NSObject *weakObjc = objc;
    }
}

上述代码中创建了一个NSObject对象objc，然后用weakObjc对objc弱引用。
当我们对一个对象进行弱引用时，底层是通过runtime来支持的，在底层会调用runtime的objc_initWeak函数：

objc_initWeak

id objc_initWeak(id *location, id newObj)
{
    if (!newObj) {
        *location = nil;
        return nil;
    }

    return storeWeak<DontHaveOld, DoHaveNew, DoCrashIfDeallocating>
        (location, (objc_object*)newObj);
}

objc_initWeak函数接收了两个参数：

• id *location ：__weak指针的地址，即例子中的weak指针取地址： &weakObjc 。它是一个指针的地址。之所以要存储指针的地址，是因为最后我们要讲__weak指针指向的内容置为nil，如果仅存储指针的话，是不能够完成这个功能的。
• id newObj ：所引用的对象，即例子中的objc 。

通过源码可以看出objc_initWeak内部调用storeWeak方法。我们进入storeWeak方法内部分析其源码：

storeWeak

// Update a weak variable.
// If HaveOld is true, the variable has an existing value 
//   that needs to be cleaned up. This value might be nil.
// If HaveNew is true, there is a new value that needs to be 
//   assigned into the variable. This value might be nil.
// If CrashIfDeallocating is true, the process is halted if newObj is 
//   deallocating or newObj's class does not support weak references. 
//   If CrashIfDeallocating is false, nil is stored instead.
enum CrashIfDeallocating {
    DontCrashIfDeallocating = false, DoCrashIfDeallocating = true
};
template <HaveOld haveOld, HaveNew haveNew,
          CrashIfDeallocating crashIfDeallocating>
static id 
storeWeak(id *location, objc_object *newObj)
{
    assert(haveOld  ||  haveNew);
    if (!haveNew) assert(newObj == nil);

    Class previouslyInitializedClass = nil;
    id oldObj;
    SideTable *oldTable;
    SideTable *newTable;

    // Acquire locks for old and new values.
    // Order by lock address to prevent lock ordering problems. 
    // Retry if the old value changes underneath us.
 retry:
    // 如果weak指针之前弱引用过一个obj，则将这个obj所对应的SideTable取出，赋值给oldTable
    if (haveOld) {
        oldObj = *location;
        oldTable = &SideTables()[oldObj];
    } else {
        // 没有弱引用过，则oldTable = nil
        oldTable = nil;
    }
    // 如果weak指针要弱引用一个新的obj，则将该obj对应的SideTable取出，赋值给newTable
    if (haveNew) {
        newTable = &SideTables()[newObj];
    } else {
        newTable = nil;
    }
    // 加锁操作，防止多线程中竞争冲突
    SideTable::lockTwo<haveOld, haveNew>(oldTable, newTable);
    // location 应该与 oldObj 保持一致，如果不同，说明当前的 location 已经处理过 oldObj 可是又被其他线程所修改
    if (haveOld  &&  *location != oldObj) {
        SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
        goto retry;
    }

    // Prevent a deadlock between the weak reference machinery
    // and the +initialize machinery by ensuring that no 
    // weakly-referenced object has an un-+initialized isa.
    if (haveNew  &&  newObj) {
        Class cls = newObj->getIsa();
        // 如果cls还没有初始化，先初始化，再尝试设置弱引用
        if (cls != previouslyInitializedClass  &&  
            !((objc_class *)cls)->isInitialized()) 
        {
            SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
            _class_initialize(_class_getNonMetaClass(cls, (id)newObj));

            // If this class is finished with +initialize then we're good.
            // If this class is still running +initialize on this thread 
            // (i.e. +initialize called storeWeak on an instance of itself)
            // then we may proceed but it will appear initializing and 
            // not yet initialized to the check above.
            // Instead set previouslyInitializedClass to recognize it on retry.
            // 完成初始化后进行标记
            previouslyInitializedClass = cls;
            // newObj 初始化后，重新获取一遍newObj
            goto retry;
        }
    }

    // Clean up old value, if any.
    // 如果weak指针之前弱引用过别的对象oldObj，则调用weak_unregister_no_lock，在oldObj的weak_entry_t中移除该weak指针地址
    if (haveOld) {
        weak_unregister_no_lock(&oldTable->weak_table, oldObj, location);
    }

    // Assign new value, if any.
    // 如果weak指针需要弱引用新的对象newObj
    if (haveNew) {
        // 调用weak_register_no_lock方法，将weak指针的地址记录到newObj对应的weak_entry_t中
        newObj = (objc_object *)
            weak_register_no_lock(&newTable->weak_table, (id)newObj, location, 
                                  crashIfDeallocating);
        // weak_register_no_lock returns nil if weak store should be rejected

        // Set is-weakly-referenced bit in refcount table.
        // 更新newObj的isa指针的weakly_referenced bit标志位
        if (newObj  &&  !newObj->isTaggedPointer()) {
            newObj->setWeaklyReferenced_nolock();
        }

        // Do not set *location anywhere else. That would introduce a race.
        // *location 赋值，也就是将weak指针直接指向了newObj，而且没有将newObj的引用计数+1
        *location = (id)newObj;
    }
    else {
        // No new value. The storage is not changed.
    }
    
    SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);

    return (id)newObj;
}

在storeWeak函数源码一开始，官方就先为我们解释了HaveOld、HaveNew、 CrashIfDeallocating三个模板的含义：

• HaveOld：weak指针之前是否已经指向了一个弱引用
• HaveNew：weak指针是否需要指向一个新引用
• CrashIfDeallocating：如果被弱引用的对象正在析构，此时再弱引用该对象，是否应该crash。

在storeWeak函数源码中有两个函数我们要重点分析一下：

// 将 weak 指针指向的地址从 obj 的 weak_entry_t 中移除
weak_unregister_no_lock  
// 将 weak 指针指向的地址注册到 obj 对应的 weak_entry_t 中
weak_register_no_lock   

weak_register_no_lock

我们直接进入weak_register_no_lock函数内部分析其源码：

id weak_register_no_lock(weak_table_t *weak_table, id referent_id, 
                      id *referrer_id, bool crashIfDeallocating)
{
    //首先获取需要弱引用对象
    objc_object *referent = (objc_object *)referent_id;
    objc_object **referrer = (objc_object **)referrer_id;
    // 如果被弱引用对象referent为nil 或者被弱引用对象采用了TaggedPointer计数方式，则直接返回
    if (!referent  ||  referent->isTaggedPointer()) return referent_id;

    // ensure that the referenced object is viable
    // 确保被引用的对象可用（没有在析构，同时应该支持weak弱引用）
    bool deallocating;
    if (!referent->ISA()->hasCustomRR()) {
        deallocating = referent->rootIsDeallocating();
    }
    else {
        BOOL (*allowsWeakReference)(objc_object *, SEL) = 
            (BOOL(*)(objc_object *, SEL))
            object_getMethodImplementation((id)referent, 
                                           SEL_allowsWeakReference);
        if ((IMP)allowsWeakReference == _objc_msgForward) {
            return nil;
        }
        deallocating =
            ! (*allowsWeakReference)(referent, SEL_allowsWeakReference);
    }
    // 如果是正在析构的对象，那么不能够被弱引用
    if (deallocating) {
        if (crashIfDeallocating) {
            _objc_fatal("Cannot form weak reference to instance (%p) of "
                        "class %s. It is possible that this object was "
                        "over-released, or is in the process of deallocation.",
                        (void*)referent, object_getClassName((id)referent));
        } else {
            return nil;
        }
    }

    // now remember it and where it is being stored
    // 在 weak_table 中找到被弱引用对象 referent 对应的 weak_entry,并将 referrer 加入到 weak_entry 中
    weak_entry_t *entry;
    if ((entry = weak_entry_for_referent(weak_table, referent))) {
        // 如果能找到 weak_entry,则讲 referrer 插入到 weak_entry 中
        append_referrer(entry, referrer);
    } 
    else {
        // 如果找不到 weak_entry，就新建一个
        weak_entry_t new_entry(referent, referrer);
        weak_grow_maybe(weak_table);
        weak_entry_insert(weak_table, &new_entry);
    }

    // Do not set *referrer. objc_storeWeak() requires that the 
    // value not change.

    return referent_id;
}

在weak_register_no_lock函数内部，首先判断被弱引用对象是否采用了Tagged Pointer技术，如果有，则会直接返回（Tagged Pointer技术，在iOS底层原理探索 — 内存管理(一)一文中有详细介绍，不熟悉的读者可以直接跳转）。

接着，会判断被弱引用对象是否能够被weak弱引用。这里主要判断被弱引用对象是否正在被析构以及是否支持weak弱引用。如果被弱引用对象不能被弱引用，则直接返回nil。

如果可以被弱引用，则将被弱引用对象所在的weak_table中的weak_entry_t哈希数组中取出对应的weak_entry_t，如果weak_entry_t不存在，则会新建一个。然后将指向被弱引用对象地址的指针referrer通过函数append_referrer插入到对应的weak_entry_t引用数组。至此就完成了弱引用。

我们进入append_referrer函数内部，分析系统是如何将referrer插入到weak_entry_t中的。

append_referrer

static void append_referrer(weak_entry_t *entry, objc_object **new_referrer)
{
    // 如果weak_entry 使用静态数组 inline_referrers
    if (! entry->out_of_line()) {
        // Try to insert inline.
        // 尝试将 referrer 插入数组
        for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
            if (entry->inline_referrers[i] == nil) {
                entry->inline_referrers[i] = new_referrer;
                return;
            }
        }

        // Couldn't insert inline. Allocate out of line.
        // 如果inline_referrers的位置已经存满了，则要转型为 referrers，动态数组
        weak_referrer_t *new_referrers = (weak_referrer_t *)
            calloc(WEAK_INLINE_COUNT, sizeof(weak_referrer_t));
        // This constructed table is invalid, but grow_refs_and_insert
        // will fix it and rehash it.
        for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
            new_referrers[i] = entry->inline_referrers[i];
        }
        entry->referrers = new_referrers;
        entry->num_refs = WEAK_INLINE_COUNT;
        entry->out_of_line_ness = REFERRERS_OUT_OF_LINE;
        entry->mask = WEAK_INLINE_COUNT-1;
        entry->max_hash_displacement = 0;
    }

    assert(entry->out_of_line());
    // 如果动态数组中元素个数大于或等于数组总空间的3/4，则扩展数组空间为当前长度的一倍，然后将 referrer 插入数组
    if (entry->num_refs >= TABLE_SIZE(entry) * 3/4) {
        return grow_refs_and_insert(entry, new_referrer);
    }
    // 如果不需要扩容，直接插入到weak_entry中
    // & (entry->mask) 保证 begin 的位置只能大于或等于数组的长度
    size_t begin = w_hash_pointer(new_referrer) & (entry->mask);
    size_t index = begin;
    size_t hash_displacement = 0;
    while (entry->referrers[index] != nil) {
        hash_displacement++;
        index = (index+1) & entry->mask;
        if (index == begin) bad_weak_table(entry);
    }
    if (hash_displacement > entry->max_hash_displacement) {
        entry->max_hash_displacement = hash_displacement;
    }
    weak_referrer_t &ref = entry->referrers[index];
    ref = new_referrer;
    entry->num_refs++;
}

append_referrer函数具体流程已经注释，这里就不再赘述。

如果weak指针在指向obj之前，已经弱引用了其他的对象，则需要先将weak指针从其他对象的weak_entry_t的hash数组中移除。在storeWeak方法中会调用weak_unregister_no_lock函数来做移除操作，我们来看一下weak_unregister_no_lock函数源码:

weak_unregister_no_lock

void weak_unregister_no_lock(weak_table_t *weak_table, id referent_id, 
                        id *referrer_id)
{
    // 拿到以前弱引用的对象和对象的地址
    objc_object *referent = (objc_object *)referent_id;
    objc_object **referrer = (objc_object **)referrer_id;

    weak_entry_t *entry;

    if (!referent) return;
    // 查找到以前弱引用的对象 referent 所对应的 weak_entry_t
    if ((entry = weak_entry_for_referent(weak_table, referent))) {
        // 在以前弱引用的对象 referent 所对应的 weak_entry_t 的 hash 数组中，移除弱引用 referrer
        remove_referrer(entry, referrer);
        // 移除元素之后， 要检查一下 weak_entry_t 的 hash 数组是否已经空了
        bool empty = true;
        if (entry->out_of_line()  &&  entry->num_refs != 0) {
            empty = false;
        }
        else {
            for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
                if (entry->inline_referrers[i]) {
                    empty = false; 
                    break;
                }
            }
        }
        // 如果 weak_entry_t 的hash数组已经空了，则需要将 weak_entry_t 从 weak_table 中移除
        if (empty) {
            weak_entry_remove(weak_table, entry);
        }
    }

    // Do not set *referrer = nil. objc_storeWeak() requires that the 
    // value not change.
}

weak_unregister_no_lock函数首先会在weak_table中找出以前被弱引用的对象referent对应的weak_entry_t，在weak_entry_t中移除被弱引用的对象referrer。移除元素后，判断此时weak_entry_t中是否还有元素。如果此时weak_entry_t已经没有元素了，则需要将weak_entry_t从weak_table中移除。

至此，我们就分析完了当使用weak弱引用一个OC对象时，runtime在底层的操作。下面我们分析一下当weak弱引用的OC对象销毁时，所有弱引用它的指针是如何自动设置为nil的。

dealloc实现原理

当对象的引用计数为0时，系统会调用对象的dealloc方法进行释放。在底层，runtime会调用_objc_rootDealloc函数：

- (void)dealloc {
    _objc_rootDealloc(self);
}

我们进入_objc_rootDealloc函数内部：

void
_objc_rootDealloc(id obj)
{
    assert(obj);

    obj->rootDealloc();
}

发现继续调用objc_object的rootDealloc方法，我们进入rootDealloc函数内部：

inline void
objc_object::rootDealloc()
{
    //判断对象是否采用了Tagged Pointer技术
    if (isTaggedPointer()) return;  // fixme necessary?
    //判断是否能够进行快速释放
    if (fastpath(isa.nonpointer  &&  //对象是否采用了优化的isa计数方式
                 !isa.weakly_referenced  &&  //对象没有被弱引用
                 !isa.has_assoc  &&  //对象没有关联对象
                 !isa.has_cxx_dtor  &&  //对象没有自定义的C++析构函数
                 !isa.has_sidetable_rc  //对象没有用到sideTable来做引用计数
                 ))
    {
        //如果以上判断都符合条件，就会调用C函数 free 将对象释放
        assert(!sidetable_present());
        free(this);
    } 
    else {
        //如果以上判断没有通过，做下一步处理
        object_dispose((id)this);
    }
}

在rootDealloc函数内部内部做了一些判断，首先判断对象是否采用了Tagged Pointer技术，如果是就会直接返回。

然后判断对象是否采用了优化的isa计数方式（nonpointer_isa技术），如果是，则根据一些条件来判断该对象是否能够进行快速释放。具体的判断条件已经在源码中注释了，不做赘述。

值得一提的是，在判断对象是否采用了Tagged Pointer技术时，官方加了一句注释：fixme necessary?，有必要吗？不知有何用意。

我们继续分析，进入object_dispose函数内部：

id 
object_dispose(id obj)
{
    if (!obj) return nil;

    objc_destructInstance(obj);    
    free(obj);

    return nil;
}

在object_dispose函数内部调用objc_destructInstance函数来析构对象obj，再用free(obj)函数释放内存。我们进入objc_destructInstance函数来查看都做了什么操作：

void *objc_destructInstance(id obj) 
{
    if (obj) {
        // Read all of the flags at once for performance
        bool cxx = obj->hasCxxDtor();
        bool assoc = obj->hasAssociatedObjects();

        // This order is important.
        // 如果有C++析构函数，则从类中销毁C++析构函数
        if (cxx) object_cxxDestruct(obj); 
        // 如果有关联对象，则移除所有的关联对象，并将其自身从Association Manager的map中移除
        if (assoc) _object_remove_assocations(obj); 
        // 继续清理其它相关的引用
        obj->clearDeallocating(); 
    }
    return obj;
}

通过源码和注释可以看到，在objc_destructInstance函数内部会做销毁C++析构函数以及移除关联对象的操作。然后继续调用objc_object的clearDeallocating函数做下一步处理。我们来到clearDeallocating函数内部：

inline void 
objc_object::clearDeallocating()
{
    if (slowpath(!isa.nonpointer)) {
        // Slow path for raw pointer isa.
        // 如果要释放的对象没有采用了优化过的isa引用计数
        sidetable_clearDeallocating();
    }
    else if (slowpath(isa.weakly_referenced  ||  isa.has_sidetable_rc)) {
        // Slow path for non-pointer isa with weak refs and/or side table data.
        // 如果要释放的对象采用了优化过的isa引用计数，并且有弱引用或者使用了sideTable的辅助引用计数
        clearDeallocating_slow();
    }

    assert(!sidetable_present());
}

在clearDeallocating函数内部会根据要释放的对象是否采用了优化过的isa做引用计数分成两种情况：

1、如果要释放的对象没有采用了优化过的isa引用计数

那么就会调用sidetable_clearDeallocating()函数做进一步处理：

void 
objc_object::sidetable_clearDeallocating()
{
    // 在全局的SideTables中，以this指针(要释放的对象)为key，找到对应的SideTable
    SideTable& table = SideTables()[this];

    // clear any weak table items
    // clear extra retain count and deallocating bit
    // (fixme warn or abort if extra retain count == 0 ?)
    table.lock();
    //在散列表SideTable中找到对应的引用计数表RefcountMap，拿到要释放的对象的引用计数
    RefcountMap::iterator it = table.refcnts.find(this);
    if (it != table.refcnts.end()) {
        //如果要释放的对象被弱引用了，通过weak_clear_no_lock函数将指向该对象的弱引用指针置为nil
        if (it->second & SIDE_TABLE_WEAKLY_REFERENCED) {
            weak_clear_no_lock(&table.weak_table, (id)this);
        }
        //从引用计数表中擦除该对象的引用计数
        table.refcnts.erase(it);
    }
    table.unlock();
}

具体流程已经标注了注释，不再赘述。

2、如果要释放的对象采用了优化过的isa引用计数

并且该对象有弱引用或者使用了sideTable的辅助引用计数，就会调用clearDeallocating_slow()函数做进一步处理：

NEVER_INLINE void
objc_object::clearDeallocating_slow()
{
    assert(isa.nonpointer  &&  (isa.weakly_referenced || isa.has_sidetable_rc));
    // 在全局的SideTables中，以this指针(要释放的对象)为key，找到对应的SideTable
    SideTable& table = SideTables()[this];
    table.lock();
    if (isa.weakly_referenced) {
        //要释放的对象被弱引用了，通过weak_clear_no_lock函数将指向该对象的弱引用指针置为nil
        weak_clear_no_lock(&table.weak_table, (id)this);
    }
    //使用了sideTable的辅助引用计数,直接在SideTable中擦除该对象的引用计数
    if (isa.has_sidetable_rc) {
        table.refcnts.erase(this);
    }
    table.unlock();
}

以上两种情况都涉及到weak_clear_no_lock函数，这个函数的作用就是将指向被弱引用对象的弱引用指针置为nil。我们来到weak_clear_no_lock函数内部分析其过程：

void 
weak_clear_no_lock(weak_table_t *weak_table, id referent_id) 
{
    //获取被弱引用对象的地址
    objc_object *referent = (objc_object *)referent_id;
    // 根据对象地址找到被弱引用对象referent在weak_table中对应的weak_entry_t
    weak_entry_t *entry = weak_entry_for_referent(weak_table, referent); 
    if (entry == nil) {
        /// XXX shouldn't happen, but does with mismatched CF/objc
        //printf("XXX no entry for clear deallocating %p\n", referent);
        return;
    }

    // zero out references
    weak_referrer_t *referrers;
    size_t count;
    
    // 找出弱引用该对象的所有weak指针地址数组
    if (entry->out_of_line()) {
        referrers = entry->referrers;
        count = TABLE_SIZE(entry);
    } 
    else {
        referrers = entry->inline_referrers;
        count = WEAK_INLINE_COUNT;
    }
    // 遍历取出每个weak指针的地址
    for (size_t i = 0; i < count; ++i) {
        objc_object **referrer = referrers[i]; 
        if (referrer) {
            // 如果weak指针确实弱引用了对象 referent，则将weak指针设置为nil
            if (*referrer == referent) { 
                *referrer = nil;
            }
            // 如果所存储的weak指针没有弱引用对象 referent，这可能是由于runtime代码的逻辑错误引起的，报错
            else if (*referrer) { 
                _objc_inform("__weak variable at %p holds %p instead of %p. "
                             "This is probably incorrect use of "
                             "objc_storeWeak() and objc_loadWeak(). "
                             "Break on objc_weak_error to debug.\n", 
                             referrer, (void*)*referrer, (void*)referent);
                objc_weak_error();
            }
        }
    }
    weak_entry_remove(weak_table, entry);
}

至此，我们就分析完了当对象的引用计数为0时，系统会调用对象的dealloc方法进行释放的整个流程，相信在分析的过程中，大家也明白了为什么被weak修饰的对象在释放时，所有弱引用该对象的指针都会被设置为nil的原因。

dealloc方法进行释放的整个流程如下图所示：

流程图.jpeg

总结

分析完weak底层源码实现，我们可以将其原理概括为：
runtime维护了一个弱引用表，将所有弱引用obj的指针地址都保存在obj对应的weak_entry_t中。
初始化时runtime会调用objc_initWeak函数，初始化一个新的weak指针指向对象地址
添加引用时，objc_initweak函数会调用objc_storeWeak函数，作用是更新指针指向，创建对应的弱引用表。
释放时，通过dealloc函数逐层判断，最终调用clearDeallocating函数，首先根据对象地址获取所有weak指针地址的数组，然后遍历这个数组把对应的数据清空置为nil 。同时，将weak_entry_t移除出弱引用表weak_table。

更多技术知识请关注微信公众号
iOS进阶

iOS进阶.jpg